quickrun.vim の設定晒し

ちょっと設定をゴニョゴニョしながら見直したのでついでに晒します。
前回、C++ の設定を晒した時よりは読みやすいかと。

[vimrc]

" g:quickrun_config の初期化
if !exists("g:quickrun_config")
    let g:quickrun_config={}
endif

" デフォルトの設定
" 非同期で実行
" 出力先
" エラー : quickfix
" 成功   : buffer
let g:quickrun_config["_"] = {
    \ "runner/vimproc/updatetime" : 80,
    \ "outputter/buffer/split" : ":rightbelow 8sp",
    \ "outputter/error/error" : "quickfix",
    \ "outputter/error/success" : "buffer",
    \ "outputter" : "error",
    \ "runner" : "vimproc",
\ }

" コンパイラ言語用の outputter
" :QuickRun -outputter
" プロセスの実行中しているときは、buffer に出力し、
" プロセスが終了したら、quickfix へ出力を行う
let compile = quickrun#outputter#multi#new()
let compile.config.targets = ["buffer", "quickfix"]
function! compile.init(session)
    " quickfix を閉じる
    :cclose
    " 元の処理を呼び出す
    call call(quickrun#outputter#multi#new().init, [a:session], self)
endfunction

function! compile.finish(session)
    call call(quickrun#outputter#multi#new().finish, [a:session], self)
    " 出力バッファの削除
    bwipeout [quickrun
endfunction

" quickrun に outputter を登録
call quickrun#register_outputter("compile", compile)


" C++
" バイナリの出力のみ行う(実行は別)
let g:quickrun_config["cpp"] = {
\    "type"    : "cpp",
\    "command" : "g++",
\    "cmdopt"    : " -std=gnu++0x -Wall",
\    "outputter" : "compile"
\}

" F#
" バイナリの出力のみ行う(実行は別)
let g:quickrun_config["fsharp"] = {
\    "type"    : "fsharp",
\    "command" : "fsc",
\    "outputter" : "compile"
\}

基本的には、quickrun.vim ですでに多くの言語の設定が定義されているので、_ で十分だと思います。
RubyPythonHaskell とかは特に別途記述しないで上記の設定のまま使っています。
コンパイラ言語の場合は、コンパイルと実行を分けたほうがストレスフリーになるので上記のような形にしています。
(わたしの場合は、コンパイルだけすることが多いので。
他に面白い設定とかあれば教えて下さい!

[quickrun.vim]

  • v 0.5.0